Harj10LV

22.11.02

Alustukset

>    restart:with(inttrans):alias(L=laplace,IL=invlaplace,u=Heaviside):

1.

>    restart: with(inttrans): alias(LL=laplace,IL=invlaplace,u=Heaviside): # Joudumme käyttämään LL-nimea, koska L on tässä tehtävässä varattu kelan induktanssille.

>    RC:=int(i1(tau),tau=0..t)/C+R*i2(t)=e(t);

RC := 1/C*int(i1(tau),tau = 0 .. t)+R*i2(t) = e(t)

>     RL:=L*diff(i1(t),t)-L*diff(i2(t),t)=R*i2(t);

RL := L*diff(i1(t),t)-L*diff(i2(t),t) = R*i2(t)

>    L:=2;C:=50*10^(-6);R:=100;e:=t->50*sin(100*t);

L := 2

C := 1/20000

R := 100

e := proc (t) options operator, arrow; 50*sin(100*t) end proc

>    LRC:=LL(RC,t,s);

LRC := 20000*LL(i1(t),t,s)/s+100*LL(i2(t),t,s) = 5000/(s^2+10000)

>    LRL:=LL(RL,t,s);

LRL := 2*s*LL(i1(t),t,s)-2*i1(0)-2*s*LL(i2(t),t,s)+2*i2(0) = 100*LL(i2(t),t,s)

>    AE:=i1(0)=0,i2(0)=0;

AE := i1(0) = 0, i2(0) = 0

>    LRC:=subs(AE,LRC);LRL:=subs(AE,LRL);

LRC := 20000*LL(i1(t),t,s)/s+100*LL(i2(t),t,s) = 5000/(s^2+10000)

LRL := 2*s*LL(i1(t),t,s)-2*s*LL(i2(t),t,s) = 100*LL(i2(t),t,s)

>    solve({LRC,LRL},{LL(i1(t),t,s),LL(i2(t),t,s)});

{LL(i1(t),t,s) = 50*s*(s+50)/(s^4+20000*s^2+200*s^3+2000000*s+100000000), LL(i2(t),t,s) = 50/(s^4+20000*s^2+200*s^3+2000000*s+100000000)*s^2}

>    I12:=subs(%,[LL(i1(t),t,s),LL(i2(t),t,s)]);

I12 := [50*s*(s+50)/(s^4+20000*s^2+200*s^3+2000000*s+100000000), 50/(s^4+20000*s^2+200*s^3+2000000*s+100000000)*s^2]

>    I1:=I12[1]: I2:=I12[2]:

>    I1:=convert(I1,parfrac,s);I2:=convert(I2,parfrac,s);

I1 := 25/2/(s+100)^2-1/(4*(s+100))+1/4*(s+50)/(s^2+10000)

I2 := 25/(s+100)^2-1/(4*(s+100))+1/4*s/(s^2+10000)

>    i1:=IL(I1,s,t);

i1 := 1/8*sin(100*t)+1/4*cos(100*t)+(25/2*t-1/4)*exp(-100*t)

>    i2:=IL(I2,s,t);

i2 := 1/4*cos(100*t)+(25*t-1/4)*exp(-100*t)

>    plot([e(t)/R,i1,i2],t=0..3/10,color=[gray,red,blue],legend=["Syöttöjännite normeerattuna R:llä","Virta i1","Virta i2"]);

[Maple Plot]

2.

>    restart:with(inttrans):alias(L=laplace,IL=invlaplace,u=Heaviside):

>    dy1:=m1*diff(y1(t),t,t)=-k1*y1(t)+k2*(y2(t)-y1(t));
dy2:=m2*diff(y2(t),t,t)=-k2*(y2(t)-y1(t))-k3*y2(t);

dy1 := m1*diff(y1(t),`$`(t,2)) = -k1*y1(t)+k2*(y2(t)-y1(t))

dy2 := m2*diff(y2(t),`$`(t,2)) = -k2*(y2(t)-y1(t))-k3*y2(t)

>    AE1:=y1(0)=0,D(y1)(0)=1; AE2:=y2(0)=0,D(y2)(0)=-1;

AE1 := y1(0) = 0, D(y1)(0) = 1

AE2 := y2(0) = 0, D(y2)(0) = -1

>    Ldy1:=L(dy1,t,s): Ldy1:=subs(AE1,Ldy1);

Ldy1 := m1*(s^2*L(y1(t),t,s)-1) = -k1*L(y1(t),t,s)+k2*(L(y2(t),t,s)-L(y1(t),t,s))

>    Ldy2:=L(dy2,t,s): Ldy2:=subs(AE2,Ldy2);

Ldy2 := m2*(s^2*L(y2(t),t,s)+1) = -k2*(L(y2(t),t,s)-L(y1(t),t,s))-k3*L(y2(t),t,s)

>    YY:=solve({Ldy1,Ldy2},{L(y1(t),t,s),L(y2(t),t,s)});

YY := {L(y1(t),t,s) = (k2*m1-k2*m2+m1*k3+m1*s^2*m2)/(m1*s^4*m2+m1*s^2*k2+m1*s^2*k3+k1*m2*s^2+k1*k2+k1*k3+k2*m2*s^2+k2*k3), L(y2(t),t,s) = -(-k2*m1+m1*s^2*m2+k1*m2+k2*m2)/(m1*s^4*m2+m1*s^2*k2+m1*s^2*k3+...
YY := {L(y1(t),t,s) = (k2*m1-k2*m2+m1*k3+m1*s^2*m2)/(m1*s^4*m2+m1*s^2*k2+m1*s^2*k3+k1*m2*s^2+k1*k2+k1*k3+k2*m2*s^2+k2*k3), L(y2(t),t,s) = -(-k2*m1+m1*s^2*m2+k1*m2+k2*m2)/(m1*s^4*m2+m1*s^2*k2+m1*s^2*k3+...

>    Y1:=subs(YY,L(y1(t),t,s));
Y2:=subs(YY,L(y2(t),t,s));

Y1 := (k2*m1-k2*m2+m1*k3+m1*s^2*m2)/(m1*s^4*m2+m1*s^2*k2+m1*s^2*k3+k1*m2*s^2+k1*k2+k1*k3+k2*m2*s^2+k2*k3)

Y2 := -(-k2*m1+m1*s^2*m2+k1*m2+k2*m2)/(m1*s^4*m2+m1*s^2*k2+m1*s^2*k3+k1*m2*s^2+k1*k2+k1*k3+k2*m2*s^2+k2*k3)

Maplella kun lasketaan, niin voidaan kivuttomasti viedä tähän pisteeseen yleisin symbolein. Tässä nyt viimeistään täytyy sijoittaa arvot.

>    m1:=10: m2:=10: k1:=20: k2:=20: k3:=40:

>    Y1; Y1:=normal(Y1); # Supistaminen onnistuus sekä komennolla normal ...

(400+100*s^2)/(100*s^4+1000*s^2+2000)

Y1 := (4+s^2)/(s^4+10*s^2+20)

>    Y2; Y2:=simplify(Y2); # ... että simplify.

-(200+100*s^2)/(100*s^4+1000*s^2+2000)

Y2 := -(2+s^2)/(s^4+10*s^2+20)

Nimittäjä pitää jakaa tekijöihin. (Tarvitaan sitä kuuluisaa 2. asteen yhtälön ratkaisukaavaa!)

>    nimittaja:=denom(Y1);

nimittaja := s^4+10*s^2+20

>    juuret:=solve(nimittaja=0,s);

juuret := -(-5+5^(1/2))^(1/2), (-5+5^(1/2))^(1/2), -(-5-5^(1/2))^(1/2), (-5-5^(1/2))^(1/2)

>    nim1:=expand((s-juuret[1])*(s-juuret[2]));

nim1 := s^2+5-5^(1/2)

>    nim2:=expand((s-juuret[3])*(s-juuret[4]));

nim2 := s^2+5+5^(1/2)

Tästä päästään kiinni osamurtohajoitelmaan. Annetaan tässä nyt Maplen laskea.

Maple ei selviä ilman tietoa siitä, että kertoimien joukossa esiintyy sqrt(5)  .  Tämän ilmoitamme näin:

>    Y1:=convert(Y1,parfrac,s,sqrt(5));

Y1 := 1/10*(5-5^(1/2))/(s^2+5-5^(1/2))+1/10*(5+5^(1/2))/(s^2+5+5^(1/2))

>    Y2:=convert(Y2,parfrac,s,sqrt(5));

Y2 := 1/10*(3*5^(1/2)-5)/(s^2+5-5^(1/2))+1/10*(-5-3*5^(1/2))/(s^2+5+5^(1/2))

Tästä onnistuu käänteismuuntaminen neliöksi täydentäen, s-siirtolausetta ja cos/sin-muunnoksia soveltaen.

Annetaan Maplen hoitaa yksityiskohdat:

>    y1:=IL(Y1,s,t);

y1 := -1/10*(-5-5^(1/2))^(1/2)*sinh((-5-5^(1/2))^(1/2)*t)-1/10*(-5+5^(1/2))^(1/2)*sinh((-5+5^(1/2))^(1/2)*t)

>    y2:=IL(Y2,s,t);

y2 := 1/20*(-5-5^(1/2))^(1/2)*(1+5^(1/2))*sinh((-5-5^(1/2))^(1/2)*t)-1/20*(-5+5^(1/2))^(1/2)*(5^(1/2)-1)*sinh((-5+5^(1/2))^(1/2)*t)

>    y1:=convert(y1,exp):evalc(%):simplify(%);

1/10*(5+5^(1/2))^(1/2)*sin((5+5^(1/2))^(1/2)*t)+1/10*(5-5^(1/2))^(1/2)*sin((5-5^(1/2))^(1/2)*t)

>    y2:=convert(y2,exp):evalc(%):simplify(%);

-1/20*(5+5^(1/2))^(1/2)*sin((5+5^(1/2))^(1/2)*t)-1/20*(5-5^(1/2))^(1/2)*sin((5-5^(1/2))^(1/2)*t)-1/20*(5+5^(1/2))^(1/2)*sin((5+5^(1/2))^(1/2)*t)*5^(1/2)+1/20*(5-5^(1/2))^(1/2)*sin((5-5^(1/2))^(1/2)*t)*...

>    y2:=collect(%,{sin((5+5^(1/2))^(1/2)*t),sin((5-5^(1/2))^(1/2)*t)});

y2 := (-1/20*(5+5^(1/2))^(1/2)-1/20*(5+5^(1/2))^(1/2)*5^(1/2))*sin((5+5^(1/2))^(1/2)*t)+(-1/20*(5-5^(1/2))^(1/2)+1/20*(5-5^(1/2))^(1/2)*5^(1/2))*sin((5-5^(1/2))^(1/2)*t)

>    y2:=map(simplify,y2);

y2 := -1/20*(5+5^(1/2))^(1/2)*(1+5^(1/2))*sin((5+5^(1/2))^(1/2)*t)+1/20*(5-5^(1/2))^(1/2)*(5^(1/2)-1)*sin((5-5^(1/2))^(1/2)*t)

>    plot([y1,y2],t=0..10);

[Maple Plot]

3.

>    restart:with(inttrans):alias(L=laplace,IL=invlaplace,u=Heaviside):

>    dy:=diff(y(t),t,t)+2*diff(y(t),t)+y(t)=Dirac(t)-u(t-2*Pi);

dy := diff(y(t),`$`(t,2))+2*diff(y(t),t)+y(t) = Dirac(t)-u(t-2*Pi)

>    AE:=y(0)=0,D(y)(0)=0:

>    Ldy:=L(dy,t,s);

Ldy := s*(s*L(y(t),t,s)-y(0))-D(y)(0)+2*s*L(y(t),t,s)-2*y(0)+L(y(t),t,s) = 1-exp(-2*s*Pi)/s

>    Ldy:=subs(AE,Ldy);

Ldy := s^2*L(y(t),t,s)+2*s*L(y(t),t,s)+L(y(t),t,s) = 1-exp(-2*s*Pi)/s

>    Y:=solve(Ldy,L(y(t),t,s));

Y := (s-exp(-2*s*Pi))/s/(s^2+2*s+1)

>    nim:=factor(denom(Y));

nim := s*(s+1)^2

>    Y1:=s/nim;

Y1 := 1/((s+1)^2)

>    y1:=IL(Y1,s,t); #

y1 := t*exp(-t)

                                                        1/(s^2)  :n muunnos ja s-siirto  (s - (-1)) .

>    Y2perexp:=-1/nim;

Y2perexp := -1/(s*(s+1)^2)

>    Y2perexp:=convert(%,parfrac,s);

Y2perexp := 1/((s+1)^2)-1/s+1/(s+1)

Keskimmäinen jo muunnettiin, muut suoraan:

>    f2:=IL(Y2perexp,s,t);

f2 := -1+(t+1)*exp(-t)

                               exp(-2*s*Pi)   aiheuttaa t-siirron

>    y2:=subs(t=t-2*Pi,f2)*u(t-2*Pi);

y2 := (-1+(t-2*Pi+1)*exp(-t+2*Pi))*u(t-2*Pi)

>    y:=y1+y2;

y := t*exp(-t)+(-1+(t-2*Pi+1)*exp(-t+2*Pi))*u(t-2*Pi)

>    L(y,t,s): simplify(%); Y; # Tarkistus, oikein meni.

-(-s+exp(-2*s*Pi))/s/(s+1)^2

(s-exp(-2*s*Pi))/s/(s^2+2*s+1)

>    plot([-u(t-2*Pi),y],t=0..25,numpoints=100,axes=boxed);

[Maple Plot]

>    plots[display](%,view=[5..8,-0.4..0.1]);

>   

[Maple Plot]

4.

>    restart:with(inttrans):alias(L=laplace,IL=invlaplace,u=Heaviside):

>    konv:=(f,g,t)->int(f(tau)*g(t-tau),tau=0..t);

konv := proc (f, g, t) options operator, arrow; int(f(tau)*g(t-tau),tau = 0 .. t) end proc

a)

>    F:=1/(s-a);

F := 1/(s-a)

>    f:=t->exp(a*t);

f := proc (t) options operator, arrow; exp(a*t) end proc

>    tulos:=konv(f,f,t);

tulos := exp(a*t)*t

>    L(%,t,s); #Tarkistus.

1/((s-a)^2)

b)

>    F1:=1/s^2; F2:=1/(s^2+omega^2);

F1 := 1/(s^2)

F2 := 1/(s^2+omega^2)

>    f1:=IL(F1,s,t); f2:=IL(F2,s,t);

f1 := t

f2 := 1/omega*sin(omega*t)

>    f1:=unapply(f1,t): f2:=unapply(f2,t):

>    f:=konv(f1,f2,t);  # Tämä on siis kysytty käänteismuunnos:

f := (omega*t-sin(omega*t))/omega^3

>    L(f,t,s);simplify(%);   # Tarkistus, ok.

1/omega^3*(omega/s^2-omega/(s^2+omega^2))

1/(s^2*(s^2+omega^2))

c)

>    F1:=s/(s^2+omega^2) ; F2:=1/(s^2+omega^2);

F1 := s/(s^2+omega^2)

F2 := 1/(s^2+omega^2)

>    f1:=unapply(IL(F1,s,t),t);

f1 := proc (t) options operator, arrow; cos(omega*t) end proc

>    f2:=unapply(IL(F2,s,t),t);

f2 := proc (t) options operator, arrow; 1/omega*sin(omega*t) end proc

>    f:=konv(f1,f2,t);  # Tässä vastaus.

f := 1/2*sin(omega*t)/omega*t

>    L(f,t,s);  #Tarkistus, oikein meni.

1/(s^2+omega^2)^2*s

5.

>    restart:with(inttrans):alias(L=laplace,IL=invlaplace,u=Heaviside):

>    dy:=diff(y(t),t,t)+omega^2*y(t)=r(t);

dy := diff(y(t),`$`(t,2))+omega^2*y(t) = r(t)

>    AE:=y(0)=y0, D(y)(0)=v0;

AE := y(0) = y0, D(y)(0) = v0

>    Ldy:=L(dy,t,s);

Ldy := s*(s*L(y(t),t,s)-y(0))-D(y)(0)+omega^2*L(y(t),t,s) = L(r(t),t,s)

>    Ldy:=subs(AE,Ldy);

>   

Ldy := s*(s*L(y(t),t,s)-y0)-v0+omega^2*L(y(t),t,s) = L(r(t),t,s)

>    Ldy:=subs(L(r(t),t,s)=R(s),Ldy);

Ldy := s*(s*L(y(t),t,s)-y0)-v0+omega^2*L(y(t),t,s) = R(s)

>    Y:=solve(Ldy,L(y(t),t,s));

Y := (s*y0+v0+R(s))/(s^2+omega^2)

>    Ytr:=(s*y0+v0)/(s^2+omega^2);
Yss:=(R(s))/(s^2+omega^2);

Ytr := (s*y0+v0)/(s^2+omega^2)

Yss := R(s)/(s^2+omega^2)

>    ytr:=IL(Ytr,s,t);

ytr := y0*cos(omega*t)+v0/omega*sin(omega*t)

>    Q:=1/(s^2+omega^2);

Q := 1/(s^2+omega^2)

>    q:=unapply(IL(Q,s,t),t);

q := proc (t) options operator, arrow; 1/omega*sin(omega*t) end proc

>    yss:=konv(q,r,t);

yss := konv(q,r,t)

>    y:=ytr+yss;

y := y0*cos(omega*t)+v0/omega*sin(omega*t)+konv(q,r,t)

Kaunis ratkaisukaava.

6.

>    restart: with(inttrans): alias(L=laplace,IL=invlaplace,u=Heaviside):
plots[setoptions](axes=boxed):

>    interface(showassumed=2):

a) KRE Exa 4 ss. 271-272

>    dyht:=diff(y(t),t,t)+3*diff(y(t),t)+2*y(t)=r(t);

dyht := diff(y(t),`$`(t,2))+3*diff(y(t),t)+2*y(t) = r(t)

>    r:=t->u(t-1)-u(t-2);

r := proc (t) options operator, arrow; u(t-1)-u(t-2) end proc

>    plot(r,0..3,title="Herätteenä neliöaalto, välin [1,2] karakt. fkt",scaling=constrained);

[Maple Plot]

>    AE:=y(0)=0,D(y)(0)=0;

AE := y(0) = 0, D(y)(0) = 0

>    Ldyht:=L(dyht,t,s);

Ldyht := s*(s*L(y(t),t,s)-y(0))-D(y)(0)+3*s*L(y(t),t,s)-3*y(0)+2*L(y(t),t,s) = exp(-s)/s-exp(-2*s)/s

>    Ldyht:=subs(AE,Ldyht);

Ldyht := s^2*L(y(t),t,s)+3*s*L(y(t),t,s)+2*L(y(t),t,s) = exp(-s)/s-exp(-2*s)/s

>    Y:=solve(Ldyht,L(y(t),t,s));

Y := (exp(-s)-exp(-2*s))/s/(s^2+3*s+2)

>    F:=1/denom(Y); es:=numer(Y);

F := 1/(s*(s^2+3*s+2))

es := exp(-s)-exp(-2*s)

>    F:=convert(F,parfrac,s);

F := 1/(2*(s+2))+1/(2*s)-1/(s+1)

Tästäpä on helppo käänteismuuntaa t-siirtolauseen avulla. Antaa nyt Maplen hoitaa:

>    yy:=IL(es*F,s,t);

yy := (-exp(-t+1)+1/2*exp(-2*t+2)+1/2)*u(t-1)+(-1/2+exp(-t+2)-1/2*exp(-2*t+4))*u(t-2)

>    plot([r(t),yy],t=0..6,legend=["Heräte","Vaste"]);

[Maple Plot]

>   

b)

Lasketaan pisteeseen t=1 keskitetyn delta -jonon vaste. Ts. otetaan jono suorakulmiopulsseja, joiden   leveys = epsilon  ja korkeus = 1/epsilon .

eli impulssi = 1  (jos kyseessä on voima). Olemme käyttäneet luennolla ja www-viitteissämme merkintää   delta[epsilon](t-a)  . Tässä siis a = 1 .

Määritellään mieluummin symmetrisesti samalla tavoin kuin luennolla (eikä KRE-tavalla).

>    d1:=(1/epsilon)*(u(t-1+epsilon/2)-u(t-1-epsilon/2));

d1 := 1/epsilon*(u(t-1+1/2*epsilon)-u(t-1-1/2*epsilon))

>    plot(subs(epsilon=0.2,d1),t=0..2,scaling=constrained);

[Maple Plot]

>    Ld1:=1/(2*epsilon*s)*(exp(-s)*exp(epsilon*s/2)-exp(-epsilon*s/2));

Ld1 := 1/2*1/epsilon/s*(exp(-s)*exp(1/2*epsilon*s)-exp(-1/2*epsilon*s))

>    dyht:=diff(y(t),t,t)+3*diff(y(t),t)+2*y(t)=d1;

dyht := diff(y(t),`$`(t,2))+3*diff(y(t),t)+2*y(t) = 1/epsilon*(u(t-1+1/2*epsilon)-u(t-1-1/2*epsilon))

>    AE:=y(0)=0,D(y)(0)=0;

AE := y(0) = 0, D(y)(0) = 0

>    assume(epsilon >0 , epsilon<1): # Muuten Maple ei L-muunna oikeaa puolta (eikä pidäkään).

>   

>    Ldyht:=L(dyht,t,s);

Ldyht := s*(s*L(y(t),t,s)-y(0))-D(y)(0)+3*s*L(y(t),t,s)-3*y(0)+2*L(y(t),t,s) = 1/epsilon*(exp(s*(-1+1/2*epsilon))/s-exp(s*(-1-1/2*epsilon))/s)
Ldyht := s*(s*L(y(t),t,s)-y(0))-D(y)(0)+3*s*L(y(t),t,s)-3*y(0)+2*L(y(t),t,s) = 1/epsilon*(exp(s*(-1+1/2*epsilon))/s-exp(s*(-1-1/2*epsilon))/s)

>    Ldyht:=subs(AE,Ldyht);

Ldyht := s^2*L(y(t),t,s)+3*s*L(y(t),t,s)+2*L(y(t),t,s) = 1/epsilon*(exp(s*(-1+1/2*epsilon))/s-exp(s*(-1-1/2*epsilon))/s)
Ldyht := s^2*L(y(t),t,s)+3*s*L(y(t),t,s)+2*L(y(t),t,s) = 1/epsilon*(exp(s*(-1+1/2*epsilon))/s-exp(s*(-1-1/2*epsilon))/s)

>    Y:=solve(Ldyht,L(y(t),t,s));

Y := (exp(1/2*s*(epsilon-2))-exp(-1/2*s*(epsilon+2)))/epsilon/s/(s^2+3*s+2)
Y := (exp(1/2*s*(epsilon-2))-exp(-1/2*s*(epsilon+2)))/epsilon/s/(s^2+3*s+2)

>    y:=IL(Y,s,t);

y := 1/epsilon*((exp(-t+1+1/2*epsilon)-1/2-1/2*exp(-2*t+2+epsilon))*u(t-1-1/2*epsilon)+u(t-1+1/2*epsilon)*(-exp(-t+1-1/2*epsilon)+1/2+1/2*exp(-2*t+2-epsilon)))
y := 1/epsilon*((exp(-t+1+1/2*epsilon)-1/2-1/2*exp(-2*t+2+epsilon))*u(t-1-1/2*epsilon)+u(t-1+1/2*epsilon)*(-exp(-t+1-1/2*epsilon)+1/2+1/2*exp(-2*t+2-epsilon)))

Tästä voitaisiin määrätä raja-arvo, kun epsilon  -> infinity  samaan tapaan kuin tehtiin yleisesti (otetaan exp-funktion sarjasta sopiva määrä termejä).

Demonstroimme numeerisesti ja kuvilla tilannetta.

>    y1:=subs(epsilon=1,y):y05:=subs(epsilon=0.5,y):y02:=subs(epsilon=0.2,y):y01:=subs(epsilon=0.1,y):y005:=subs(epsilon=0.05,y):

>    plot([y1,y05,y02,y01,y005],t=0..4,color=[red,blue,black,green,cyan,gold],title="Systeemin vaste kapeneviin yksikköpulsseihin",legend=["eps=1","eps=0.5","eps=0.2","eps=0.1","eps=0.05"]);

[Maple Plot]

>   

>   

>   

>    F:=1/(s*(s+1)*(s+2));

F := 1/(s*(s+1)*(s+2))

c)

Lasketaan nyt sama lasku, kun herätteenä on yksikköimpulssi hetkellä t=1, eli käytetään suoraan Diracin deltaa herätteenä.

Merkitään nyt ratkaisua x(t):llä ja vastaavasti L.muunnosta X(s):llä.

>    dy:=diff(x(t),t,t)+3*diff(x(t),t)+2*x(t)=Dirac(t-1);

dy := diff(x(t),`$`(t,2))+3*diff(x(t),t)+2*x(t) = Dirac(t-1)

>    AE:=x(0)=0,D(x)(0)=0;Ldy:=L(dy,t,s);

AE := x(0) = 0, D(x)(0) = 0

Ldy := s*(s*L(x(t),t,s)-x(0))-D(x)(0)+3*s*L(x(t),t,s)-3*x(0)+2*L(x(t),t,s) = exp(-s)

>    Ldy:=subs(AE,Ldy);

Ldy := s^2*L(x(t),t,s)+3*s*L(x(t),t,s)+2*L(x(t),t,s) = exp(-s)

>    X:=solve(Ldy,L(x(t),t,s));

X := exp(-s)/(s^2+3*s+2)

>    x:=IL(X,s,t);

x := 2*u(t-1)*exp(-3/2*t+3/2)*sinh(1/2*t-1/2)

Voitaisiin tietysti käyttää tätä muotoa, mutta saadaan sievempään (ja tutumpaan) muotoon näin:

>    convert(x,exp);expand(%);simplify(%,symbolic);x:=%;

2*u(t-1)*exp(-3/2*t+3/2)*(1/2*exp(1/2*t-1/2)-1/2*1/exp(1/2*t-1/2))

u(t-1)*exp(-3/2*t)*exp(3/2)*exp(1/2*t)*exp(-1/2)-u(t-1)*exp(-3/2*t)*exp(3/2)/exp(1/2*t)/exp(-1/2)

u(t-1)*(exp(-t+1)-exp(-2*t+2))

x := u(t-1)*(exp(-t+1)-exp(-2*t+2))

>    plot(x,t=0..20);

[Maple Plot]

>    plot([y1,x],t=0..4,color=[blue,gold]);

[Maple Plot]

>    plot([y02,x],t=0..4,color=[black,gold]);

[Maple Plot]

>    plot(y005-x,t=0..3);

[Maple Plot]

>   

b)-kohdan jono näkyy lähestyvän delta-herätettä vastaavaa tulosta. Tämä ei ole yllättävää. deltan  Laplace-muunnos määrättiin juuri

tällaisen rajaprosessin avulla (L-muunnosten raja-arvo, muunnettaessa delta -jonoa).