Pohdiskelua

Lue

• [SOL] s 15-16 Symbolien hallintaa ja periaatteita
• [HAM] s. 70 - 71 (korjaus: http://www.math.hut.fi/~apiola/maple/opas/eval.html  )

(see Heck Ch 3 Variables and names p. 65 -..  

The secret behind success of CA : free (unbound) variables  . )

Lyhyesti (North Carolinan tekstiä mukaillen)

Joukot { }, jonot, listat [ ]

Tässä vähän University of North Carolinan sivulta poimittua tekstiä:

Observe that we have now employed three different kinds of grouping symbols:  "()","{}", and "[]".  They are used for different purposes, and Maple requires that they be used correctly.  The standard parentheses "()" are used with functions as in factor(x^2-1)  and sin(Pi) .  The braces " {} " are used to group a set as in {x,y} .  The square brackets " [] " are used to pick a coordinate from a group as in sol[2] .  We will see other uses for these symbols.
Hakasulut ovat myös listasulut. Tärkeimmät tietorakenteet:

• Jono , esim:  
• > jono:=a,b,c;  
• Lista,  esim:   > lista:=[a,b,c];   
          > op(lista);    # Listan operandi on sisältönä oleva jono
• Joukko , esim:   > joukko:={a,b,c};  

                                   > op(joukko);  # Vastaavasti joukon operandi

Huom : Listan järjestys on käyttäjän hallinnassa, joukon ei.
              Joukon hyöty on ainakin se, että Maple osaa poistaa toistot ja joukko-operaatiot toimivat.

map   - funktion soveltaminen listan (tai muun rakenteen) jokaiseen alkioon (osaan)

Error, missing operator or `;`

>	lista:=[a,b,c];map(f,lista);

>	jono:=a,b,c;lista:=[a,b,c];op(lista);joukko:={a,b,c}; op(joukko);

>	map(f,jono);f(jono);

Huomaa, että jono ei ole samanlainen "paketti" kuin lista tai joukko. map-esimerkki osoittaa, että voidaksemme soveltaa tällaista operaatiota jonoon, se on ensin ympäröitävä listasuluilla []  ja lopuksi riisuttava sulut pois tuloksesta op -komennolla:

Error, missing operator or `;`

>	op(map(f,[jono]));

Funktion soveltaminen listan tms. kaikkiin alkioihin, map

vektoreihin ja matriiseihin. Siten sin([1,2,3]) antaa [sin(1),sin(2),sin(3)].

Maplessa näin ei ole, mutta se saadaan aikaan " map" :lla:

>	x:=[a,b,c]; fx:=map(f,x);

>

restart:

>	M:=Matrix([seq([seq((x+y)^(i+j),j=1..3)],i=1..2)]);

>	map(expand,M);

>

Hiukan perusteellisemmin (osittain toistaen)

Lue: [HAM] s. 30 ja ss. 76 - 84

>	restart: with(LinearAlgebra):

>	jono1:=a,b,c; jono2:=seq(x^i,i=-3..3);

>	lista1:=[jono1]; lista2:=[jono2];

>	joukko1:={jono1}; joukko2:={jono2};  # Alkioiden järjestys on "satunnainen"

>	joukko1 union {a,b,-1,1};

>	[op(lista1),op(lista2)];   # Listat liitetään liittämällä operandijonot ja ympäröimällä []:lla

>	logaritmit:=seq([i,log(i)],i=1..10);

Maplessa vaakavektoreiden lista ei ole sama kuin matriisi (kuten Mathematicassa). Se voidaan muuntaa  Matrix:lla, takaisin saadaan convert: lla .

Esitys listojen listana on hyödyllinen esimerkiksi piirrettäessä, se muoto kelpaa suoraan plot :lle.

>	logtaulu:=Transpose(Matrix([logaritmit]));

>	plot([logaritmit]);

>	convert(logtaulu,listlist);

>	convert(Transpose(logtaulu),listlist);

Vektorit ja matriisit:

>

restart:

>	pysty:=<a,b,c>; vaaka:=<1 | 2 | 3>;

>	M:=<<1,2,3>|<b,e,x>|<u,v,w>>;  # Sarakkeittain.

>	Mt:=<<1|2|3>,<b|e|x>,<u|v|w>>;  # Riveittäin

>	M.Mt;                           # Matriisikertolasku

>	convert(vaaka,list);

>	convert(pysty,list);

>	convert(M.Mt,listlist);

Tehtäviä

Miten poistaisit listasta saman alkion toistot?

Pohdiskelua

Matemaattisen funktion käsittely Maple-lausekkeena

>

f := x^2;

Määrittelemme muuttujan f, jota käytämme matemaattisen funktion tavoin. Maplen kannalta f on muuttuja , jonka arvoksi olemme sijoittaneet lausekkeen x^2

Jos haluamme laskea lausekkeen arvon eri x:n arvoilla, joudumme käyttämään subs-komentoa.

>	subs(x=5,f);

>	eval(f,x=5); # Näinkin voidaan, tätä tapaa käytetty gsg:ssä.

Jos haluat seurata lauseke/funktio-juonta, hyppää tässä kohdassa   seq- kometojen yli.

>	seq(subs(x=k, f),k=0..10);

>	a:=-4: b:=4: N:=10: h:=(b-a)/N: arvojono:=seq(subs(x=a+k*h, f),k=0..N);

>	evalf(arvojono);

VAROITUS: Kun matemaattista funktiota käsitellään lausekkeena, on oltava johdonmukainen. Siitä ei saa välillä käyttää merkintää f(x), tietenkään!

  Kokeile vaikka:

>	f(x); f(5);

Matemaattisen funktion käsittely Maple-funktiona:

>	f := x -> x^2;

>	f(x),f(y),f(5);

Tyytykäämme ensialkuun tähän. Lue kuitenkin jossain vaiheessa loppukin.

unapply  on toinen funktion määrittelytapa.

>

g := x^3;

>	g(5); # Tämä on tuhoon tuomittu.

Huomaamme nyt, että olis ollut mukavampi  käsitellä funktiona. No sehän käy:

>	g := unapply(g, x);

>

g(5);

What is the difference unapply vs  ->   ?

•  Nuolimäärittely evaluoi  (vasta) suoritusaikana.
•  unapply evaluoi (jo) määrittelyaikana.

>	a:=x^2: f:=x->a;g:=unapply(a,x);

>

f(3);

>

g(3);

>

a:=Pi;

>

f(3);

>

g(3);

Tässä tilanteessa siis nuolimääritys   ->

tomii "omituisesti", kun taas #unapply  toimi "odotetusti".

Siniset määritysrivit yllä kertovat kyllä asian hyvin, niitä kannattaa seurailla.

Jatketaan tästä (harj0):

Varoitus: Hengenvaarallista:  Älä koskaan määrittele funktiota tyyliin F(x):=lauseke;

Tällöin tulee määritellyksi funktion F arvo yhdessä pisteessä x, muilla symboleilla funktio f on määrittelemätön.

Poikkeus : Funktion määrittelyä täydentävien poikkeusarvojen  määrittelyssä tämä on hyödyllistä, esimerkki otetaan kohta.)

Palataan nyt vielä tuohon hengenvaaraan:

>

restart:

>	F(x):=x^3; # kokeillaan kiellettyä leikkiä.

Tuo on syntaksiltaan oikein, mutta hyvin hämäävää.

Mitä on F(x)

>

F(x);

Näyttää, kuin toimisi oikein. Vaan eipas toimi muilla kuin x:llä.

>	F(x),F(3),F(a),F(sin(z));

Toisin sanoen funktio on määritelty vain, kun argumenttina on symboli x

Esimerkki: Funktion määrittelyn täydentäminen poikkeusarvoilla .

Haluamme määritellä funktion, jota joskus kutsutaan nimellä sinc,   olkoon tässä vain F

>	F:=x->sin(x)/x;

>

F(0);

Error, (in F) numeric exception: division by zero

Yleinen sääntö ei määrittele F-funktiota 0:ssa, koska siinä tulee 0:lla jako.

Annamme siksi funktiolle 0:ssa sopivan arvon suoralla asetuksella:

>

F(0):=1;

>	F(a),F(1/2),F(0),F(sin(x));

>	seq(F(x),x=-2..2);evalf(%);

Remember: # evalf  means: eval uate f loating point.

• Lue lisää:
•  [HAM] ss. 62-63

Harjoitustehtävä

Määrittele polynomifunktio  .

 Määritä nollakohdat ja paikalliset minimit sekä maksimit. Piirrä funktio ja sen derivaatta.

 Tarkista laskemalla funktion arvot, että nollakohdat ovat nollakohtia.

Käsittele polynomia ensin lausekkeena ja sitten funktiona. Mitkä ovat kunkin tavan hyvät/huonot puolet.

Derivaattalauseke --  diff  

Derivaattafunktio  -- D     (Käyttele helppiä  )

 ?plot, ?solve,?fsolve ?diff, ?D

Tämäntyyppisten tehtävien, niin yksinkertaisia matemaattisesti kuin ovatkin, sujuva hallinta tekee Maple-työskentelystä nautittavaa puuhaa ja auttaa pitkälle.

Pohdiskelua
   simplify  - yleissieventäjä, ensimmäiseksi tarjoiltava.

    expand  -  kertoo auki

    collect   - kokoaa   

           ? collect  ja  kokeile joitakin esimerkkejä. Varsin hyvä komento monessa paikassa.

   factor  -  Jakaa tekijöihin.
    convert  - ... Monenmoisiin konversioihin sievennyksessä esim      convert(lauseke,parfrac,muuttuja);

  Huomaa, että lauseke ei muutu, uusi tulos palautetaan. Jos halutaan päivittää lauseke, on komennetava

              lauseke:=convert(lauseke,parfrac,muuttuja);

   solve  -  ratkaisee yhtäön tai systeemin

    fsolve - ratkaisee numeerisesti

>	(x^3+1)/(x^2-x+1);simplify(%);

>	expand((x^2-4)*(x+1)*(x-2)*(x^2+x+1));

>	factor(%);

Yhtälöistä

• [SOL] s. 11-12
• [HAM] s. Luku 6 s. 133 - 142

>	yhtalot:={2*x-5*y=12, 12*x+4*y=17};  # Kyseessä on joukko

>	ratk:= solve(yhtalot, {x,y});

Maple ei sijoita ratkaisuja muuttujille arvoiksi, vaan palauttaa sijoitussäännöt. Ne voidaan antaa suoraan

>	#subs -komennolle. Mieti seuraavan komentojonon logiikkaa!

>	subs(ratk,x),subs(ratk,y);

>	X:=subs(ratk,x); Y:=subs(ratk,y);

Tarkistaminen käy vaivattomasti:

>	subs(ratk,yhtalot);

>

Voidaan myös käyttää #lhs  (left hand side) ja   rhs  (right hand side)-tapaa, mutta se on hiukan vähemmän elegantti ja myös altis Maplen harrastamalle järjestyksen vaihtumiselle ratkaisujoukossa. Niinpä tätä tyyliä ei voida ajaa automaattisesti, vaan tuloksiin on puututtava interaktiivisesti, mikä voi olla kiusallista, jos on "vakavahenkisestä" dokumentista kyse. Joka tapauksessa tämäkin tyyli kannattaa omaksua.

>	rhs(ratk[1]);lhs(ratk[1]);

>	lhs(ratk[2])=rhs(ratk[2]);

Ratkaisun sijoittaminen muuttujan arvoksi

Tässä nyt on toisin sanoin selitetty samaa, pyyhi omasta dokustasi pois tai järjestä paremmin.

Tietysti näin:

>	X:=rhs(ratk[1]);Y:=rhs(ratk[2]);

Turvallisempi ja elegantimpi tapa (jota edellä mainostettiin):

      Suorita ratk-yhtälöiden ilmaisemat korvaamiset lausekkeessa (pelkkä) x ja
     suorita ratk-yhtälöiden ilmaisemat korvaamiset lausekkeessa (pelkkä) y .

Edellisessä y-yhtälö jää vaille käyttöä (kun pelkkä x ei sisällä y:tä) ja jälkimmäisella vastaavasta syystä x-yhtälö. ratk -joukon järjestys ei näyttele mitään osaa.

>	X:=subs(ratk,x);Y:=subs(ratk,y);

Tehokkain, mutta turvattomin tapa, joskus kylläkin tosi kätevä:   assign(ratk);

>	assign(ratk);

>	x;y;yhtalot;

>	solve(yhtalot,{x,y}); # assign-komennon jälkeen x ja y eivät ole vapaita muuttujia, josta syystä solve menee virheeseen.

Error, (in solve) a constant is invalid as a variable, -55/34, 133/68

assign(ratk);  toimii ikäänkuin ratk-yhtälöissä yhtälömerkki (=) vaihdettaisiin sijoitusmerkkin (:=)

     Yhtälöiden toteutuminen saadaan hyvin kätevästi tarkistetuksi kirjoittamalla vain yhtalot;

      Sensijaan yhtälöiden ratkaisua ei voida toistaa, ennekuin muuttujat x ja y on vapautettu arvoistaan.

>	x:='x':y:='y':solve(yhtalot,{x,y});

Tavallinen käyrien piirto

Käyräparven voi sulkea joko joukkosulkuihin { }  tai listasulkuihin [ ]  .
Jälkimmäinen lienee suositeltavaa, koska järjestys on silloin käyttäjän hallinnassa (esim jos  halutaan värit hallitusti, tms).

>	plot([sin(x),cos(x)],x=0..4*Pi);

• Ota hiiren vasemmalla kiinni kuvasta, saat kehyksen ja uudet valikot.

     Valitse sama mittakaava akseleilla  (1:1)

• Jos grafiikka alkaa hidastaa työarkin selausta, kannattaa valita EDIT-valikon alimmasta,
  Remove output.  Sitä kannattaa käyttää muutenkin silloin  tällöin. Työarkki tiivistyy (ja nopeutuu) kummasti. Outputit saa takaisin  saman EDIT-valikon toiseksi alimmaisesta execute worksheet
• Huomaa: Pi on Iso P, pieni i . (pi kirjoittuu oikean näköisesti, mutta Maple ei tunnista sitä
  muuksi kuin kreikkalaiseksi kirjaimeksi. )  [No johan tuosta huomauteltiin.]

Parametrimuotoinen piirtomatrixplot(logtaulu);

Syntaksi poikkeaa aika vähän, tämä täytyy vain oppia (tai katsoa aina uudelleen helpistä).

Aina ei ole hauskaa joutua valitsemaan hirellä, samaskaalaiisuus (ja monia muita) voidaan antaa plot-komennon tarkentimena.

>	plot([cos(t),sin(t),t=0..2*Pi],scaling=constrained);

Pisteet voidaan yhtä hyvin ajatella kompleksitason pisteinä. complexplot osaa käsitellä suoraan reaalimuuttujan kompleksiarvoista funktiota. Tässä on sekin mukava piirre, että syntaksi on luonnollisempi ja siten helpompi muistaa kuin tuossa parametrimuotoisessa R^2-piirrossa.

>	with(plots):

Warning, the name changecoords has been redefined

>	complexplot(cos(t)+I*sin(t),t=0..2*Pi,scaling=constrained,color=blue);

Edellinen voidaan ilmaista lyhyemmin eksponenttifunktion (Eulerin kaavan) avulla. Piirretään vaihteeksi pelkät pisteet.

>	complexplot(exp(I*t),t=0..2*Pi,scaling=constrained,color=cyan,style=point);

Taulukoidun datan piirto ("listaplotti")

Sometimes we will be interested in functions defined in terms of a discrete
table of values rather than a formula.  For example, consider the following table of
temperatures recorded at various times on a spring day in Raleigh.
     
   Time:  |  6:00 a.m. |  10:00 a.m. |  12:00 p.m. |  4:00 p.m. |  5:00 p.m.
  ----------------------------------------------
   Temp: |   45 deg.  |    57 deg.       |   65 deg.      |   67 deg.    |   66 deg.

                       Table of Temperatures on a Spring Day in Degrees Fahrenheit    

To plot this data you must first define the points as a list.  Since the time is recorded in a cyclic fashion, we will plot the times in the so-called "military style",  i.e.  6:00 a.m. is 0600 and  6:00 p.m. is 1800.

>	ListOfPoints := [[600,45], [1000,57], [1200,65], [1600,67], [1700,66]];

The plot  command allows you to plot a list of points and to connect them with straight lines (unless you choose another option).  This is illustrated in the next command.  Notice also the option which produces a title on the plot.

>	plot(ListOfPoints, title="Temperatures at Various Times");

While the data can be plotted in this way,  because the data is given for a discrete set of points you may prefer the style=POINT  option as illustrated in the next command.  Note also the effect of the symbol=CIRCLE  option.

>	plot(ListOfPoints, style=POINT, symbol=CIRCLE,symbolsize=15, title=`Temperatures at Various Times`);

>

Olkoon annettu numeeriset listat (Matlabissa sanoisimme vektorit) X ja Y.  Matlabin plot toimii tyyliin plot(x,y);

Maplessa täytyy muodostaa parien lista vaikkapa tähän tapaan:

>	a:=-Pi:b:=Pi:N:=20:h:=(b-a)/N:x:=seq(evalf(a+i*h),i=0..N);

Olkoot y-arvot vaikkapa sin-funktion arvoja x-pisteissä. Parijono saataisiin nyt näin:

>	xy:=[seq([x[i],sin(x[i])],i=1..N+1)];

>	plot(xy);plot(xy,style=point,symbol=circle);

Huom:   plots -pakkauksessa on listplot ja pointplot . Maplelle luonteenomaista on, että siinä on joukko redundantteja funktioita. Mielestäni on parempi oppia käyttämään harvempaa ydinfunktiojoukkoa kuin omaksua monenlaisia synonyymejä. Niissä voi toki olla joitakin uusia mahdollisuuksia, mutta esim. näissä ei välttämättä ole (kuka noita kaikkia tuhansia ehtii penkoa).

Taulukointi

Tässä teimme itse asiassa taulukon, joka on havainnollisempi usein matriisina.

>	txy:matrix(xy):linalg[transpose](xy):

Tilan säästämiseksi otetaan vähemmän dataa esimerkkiimme. Jätetäänpä myös evalf pois.

>	a:=-Pi:b:=Pi:N:=8:h:=(b-a)/N:x:=seq(a+i*h,i=0..N); xy:=[seq([x[i],sin(x[i])],i=1..N+1)]; matrix(xy);

>	linalg[transpose](xy);

>	array(xy);  # Taas synonyymi, mutta tiettyjä erojakin yleisyydessa / matriisilaskukyvyissä.

Grafiikoiden yhdistäminen, plots[display] ja textplot

Tässä tarvitaan lisägrafiikkapakkaus plots

>	restart:with(plots):

Warning, the name changecoords has been redefined

Selvitä itsellesi, mitä seuraavassa tehdään. Mieti tarkkaan, miksi jossain pitää antaa plot:lle argumentiksi

f(x) ja miksi taas jossain esim. tang. Voit sitten huvitella vaihtelemalla funktion määritelmää

ja / tai pistettä x0. Kirjoitetaan pieni malliskripti, jonkalaisia voit tehdä moninaisissa yhteyksissä.

>	x0:=1: f:=x->x^3:  # Vaihtuva syöte

>	df:=diff(f(x),x): kk:=subs(x=1,df);

>	x0:=1: tang:=f(x0)+kk*(x-x0);

>	fkuva:=plot(f(x),x=0..2,color=red): tangkuva:=plot(tang,x=0..2,color=blue): p0kuva:=plot([[x0,f(x0)]],style=point,symbol=circle,symbolsize=15,color=black):

>	display([fkuva,tangkuva,p0kuva]);

>

>

Kokeile (mutta vain kerran elämässäsi, silloinkin syvästi katuen, että olit yllytyshullu),

 mitä tapahtuu, kun vaihdat  (:) -> (;)  vaikkapa fkuva:=; . .. yllä. PLOT-tietorakenne paljastuu.

- No, mene edit-valikkoon ja -> remove output,  kyllä se siitä.

Sometimes it will be desirable to print text on a plot.   The plots  procedure textplot  will allow this. The following commands will serve as examples of the textplo t and display  routines.  Make sure you notice where colons and semicolons are used in these commands.

In the next  commands it is important to use colons to punctuate the first two statements.  Otherwise Maple will ouput an entire page of text describing the plot structure rather than the graph.  The textplot in the second command causes the text x=0.6356,y=0.5000 to be printed at the point (.6356,.5000).  The statement align=RIGHT  aligns this text to the right of the point.  

>	f := x -> exp(-x)*sin(3*x); plot1 := plot(f, 0..3):# tai plot1:=plot(f(x),x=0..3): plot2 := plots[textplot]([0.6356, 0.5000, "x=.6356, y=.5000"], align=RIGHT): plots[display]({plot1, plot2});

Huom:

plots-pakkauksen (kuten muidenkin pakkausten) funktioita voidaan käyttää myös lataamatta

koko pakkausta, tällöin pakkauksen nimeä ikäänkuin indeksoidaan ao. funktion nimellä

tyyliin   plots[display]

>

3d-grafiikkaa, animaatiot

Otetaan lämmönjohtumisesimerkki, jossa valaistaan

• 3d-pinnan piirtoa
• Animaatiota
• 3d-kuvan projektiokäyräparven piirtoa

Tarkastellaan sivuiltaan lämpöeristettyä sauvaa, jonka päät upotetaan hetkellä t=0 jäävesisäiliöihin (0 astetta) ja jonka
alkulämpötilajakauma on

>	f:=x->100*sin(Pi*x/80);

Huomaa funktiomääritys .

Olkoon sauvan pituus L=80.

Tässä tapauksessa lämpöyhtälön ratkaisuna olevasta Fourier-sarjasta tulee vain yksi termi. Ratkaisu on (sopivalla lämmönjohtumiskertoimella)

>	u:=(x,t)->100*sin((Pi*x)/80)*exp(-0.001785*t);