Mat-1.312 Matematiikan peruskurssi T2 / kevat 1996

Input := 

Pallon kahdeksanneksen massakeskipiste ja
hitausmomentti

Varmuuden vuoksi: Poistetaan mahdolliset aiemmat muuttujat:

Input := 

Remove["Global`*"]

Pisteen (x,y,z) ja akselin x=y=z yhdysvektori:

Input := 

dvekt= {x,y,z}-t {1,1,1}

Output =

{-t + x, -t + y, -t + z}

Ratkaistaan t siten, etta tama vektori on kohtisuorassa akselia vastaan (piste on
skalaaritulon merkki):

Input := 

tsol= Solve[dvekt.{1,1,1}==0,t]

Output =

       x + y + z
{{t -> ---------}}
           3

Kohtisuora etaisyys eli eo. vektorin pituus (komennon loppuun voidaan panna
lisamaare //Simplify; tama on sama asia kuin antaa seuraavana komentona
Simplify[%]):

Input := 

d= Sqrt[dvekt.dvekt/.First[tsol]]//Simplify

Output =

     2        2          2                2
Sqrt[-] Sqrt[x  - x y + y  - x z - y z + z ]
     3

Momenttien laskemiseksi on integroitava seuraavan listan alkiot kappaleen yli:

Input := 

lista= {1,x,y,z,d^2}

Output =

                 2          2                2
             2 (x  - x y + y  - x z - y z + z )
{1, x, y, z, ----------------------------------}
                             3

Tilavuusalkio pallokoordinaateissa:

Input := 

dv= r^2 Sin[th]

Output =

 2
r  Sin[th]

Integroidaan pallokoordinaateissa, jolloin koordinaattien x, y ,z paikalle on
sijoitettava niiden lausekkeet pallokoordinaateissa:

Input := 

int= Integrate[lista dv /.{x-> r Sin[th] Cos[phi],
y-> r Sin[th] Sin[phi], z-> r Cos[th]},
{r,0,R},{th,0,Pi/2},{phi,0,Pi/2}]

Output =

     3      4      4      4             5
 Pi R   Pi R   Pi R   Pi R   (-2 + Pi) R
{-----, -----, -----, -----, ------------}
   6     16     16     16         15

Massakeskipisteen suorakulmaiset koordinaatit (listan indeksit on sijoitettava kaksinkertaisten hakasulkujen sisalle):

Input := 

mkp= int[[{2,3,4}]]/int[[1]]

Output =

 3 R  3 R  3 R
{---, ---, ---}
  8    8    8

Hitausmomentti lausuttuna kokonaismassan m (= tilavuus) avulla (toinen momentti
int[[5]] on siis itse asiassa kerrottu ykkosella, koska m = Pi R^3 / 6):

Input := 

j= int[[5]] m / int[[1]]

Output =

               2
2 m (-2 + Pi) R
----------------
      5 Pi

Hitaussade, ts. se etaisyys, jolle samamassainen piste on sijoitettava, jotta
saataisiin sama hitausmomentti:

Input := 

r0= Sqrt[j/m]//PowerExpand//N

Output =

0.381251 R

Tutki viela, voitaisiinko massakeskipisteen etaisyys origosta laskea integroimalla
pallokoordinaattien muuttuja r kappaleen yli ja jakamalla kokonaismassalla.
Jos voitaisiin, niin miksi; jos ei, niin miksi ei?

Input := 

Integrate[r dv,{r,0,R},{th,0,Pi/2},{phi,0,Pi/2}]/int[[1]]

Output =

3 R
---
 4